"I Have the Strength of Ten Men" by John Timmons

The release number is 1. The story creation year is 2007. The story headline is "An example of changing the abilities of the player by interacting with another object". The story description is "This is a simple demonstration of how touching some moss gives the player great strength to remove a table that blocks your path."

Release along with the source text and a website.

The Foyer is a room. "The foyer is a nice place to start. On one of the walls, green moss is growing there. There is an exit to the north."

[The table that blocks our exit.]
The table is a supporter in the Foyer. It is fixed in place. "A table blocks the north exit."

[The magic green moss that can have one of two new properties.]
The green moss is scenery in the foyer. The green moss can be touched or untouched. The green moss is untouched. The description is "The moss, deep green in color, has the texture of a beautiful lush rug."

[A before rule for responding to the player touching the moss.]
Before touching the green moss:
	if green moss is untouched	begin;
		now the green moss is touched;
		say "As you touch the moss, a tingling sensation travels from your fingers straight up your arm.[paragraph break]You suddenly feel a little dizzy and nauseous but the feelings pass as quickly as they came.";
		stop the action;
	otherwise;
		continue the action;
	end if.

[A rule in case the player tries to take the moss.]	
Instead of taking the green moss:
	try touching the green moss instead.

[An instead rule for when the player tries to attack (break, destroy, hit, or smash) the table. If the player has touched the moss, the table will be completely removed from play.]
Instead of attacking the table:
	if green moss is untouched	begin;
		say "Useless. You just don't have the strength. Perhaps that moss on the wall is a solution.";
	otherwise;
		remove the table from play;
		say "The table is completely and absolutely obliterated. Your strength is amazing!";
	end if.

[A before rule that checks that status of the table when the player attempts to go north.]
Before going north from the Foyer:
	if table is in location	begin;
		say "Impossible with that table blocking your way.";
		stop the action;
	otherwise;
		continue the action;
	end if.
	
[An instead rule in case the player tries to get on, sit on, or stand on the table.]
Instead of entering the table:
	say "You start to get on the table but quickly realize this is not a solution."

[The following instead rule provides a response in case the player tries to either push or pull the table.]
Instead of pushing or pulling the table:
	if green moss is untouched	begin;
		say "The table will not budge.";
		stop the action;
	otherwise;
		say "The table moves easily but, because it is so large and the room is so small, it still blocks the exit north.";
	end if.

The Kitchen is north of the Foyer.