"Sidewalk" by John Timmons

The story headline is "Exploring Without Moving".
The release number is 1.
The story creation year is 2009.
The story genre is "Tutorial".
The story description is "A simple demonstration of how a story can develop simply by examining everything in sight."

Release along with the source text, a website and an interpreter.

Use American dialect.  Maximum score is 20.

Every turn:
	if score is 20 begin;
		say "Out of the corner of your eye you see a police car slowly approaching.[paragraph break]You figure it's best to move on . . . ";
		end the game saying "Well done!  You earned all 20 points.";
	end if.


When play begins:
	say "[italic type]Sidewalk[roman type] finds you reminiscing in front of the house you grew up in and serves to demonstrate how examining anything explicitly mentioned could prove useful.[paragraph break]There are twenty (20) things to examine here:  each of which will earn you one (1) point.  Finding and examining them all completes the work.
	[paragraph break][line break]"
	

A thing can be known or unknown. A thing is usually known.

Thinking about is an action applying to one visible thing.

Understand "think about [any thing]" as thinking about.

Understand "think about [any known thing]" as thinking about.

Report thinking about something unknown:
	say "[no thoughts]"
		
Report thinking about something known:
	say "[the thought of the noun][paragraph break]".

A thing has a text called thought.

Pondering is an action applying to one topic.

Understand "think about [text]" as pondering. [otherwise we get an ugly response to THINK ABOUT FOO etc.]

Report pondering:
	say "[no thoughts]"

To say no thoughts:
	say "You have no thoughts about that right now." 


Part 1 - The Player (1 point)

Instead of examining yourself for the first time:
	say "As good-looking as ever but feeling oddly anxious being here."	;
	award 1 point.
	

Part 2 - Things Carried by the Player (7 points)

The wallet is a closed openable container carried by the player. The description is "Carried for years, it's a basic single-fold black wallet."

After examining the wallet for the first time:
	award 1 point.

Rule for printing the name of the wallet:
	say "wallet";
	omit contents in listing.

Your drivers license is in the wallet. Understand "licence" as the drivers license. The description is "Your drivers license containing your photograph and home address."

After examining the drivers license for the first time:
	award 1 point.
	
Your photo id is part of the drivers license. Understand "photograph" as the photo id. The description is "These id photos always come out nasty.  You seem to recall you had been caught in the rain before this one was taken."

After examining the photo id for the first time:
	award 1 point.
	
The address is part of the drivers license. The description is "271 Scott Swamp Road,[line break]Farmington, CT  06032".

After examining the address for the first time:
	award 1 point.

The faded photograph is in the wallet. Understand "photo" as the faded photograph. The description is "Worn from living in your wallet for so long, the sight of this person still gives you butterflies."

After examining the faded photograph for the first time:
	now _person is known;
	award 1 point.
	
The _person is part of the faded photograph. _person is unknown. Understand "person" as _person. The description is "[if known]It's Jenn.  You remember the day you took this. . .  you 'thought' you were a couple.[otherwise]What person?"

After examining the known _person for the first time:
	now Jenn is known;
	award 1 point.
	
Jenn is part of the faded photograph. Jenn is unknown. The description is "[if known]Sitting under a tree, her dark hair in her face, she smiles at you over her left shoulder.[otherwise]You see no Jenn here." Understand "tree", "hair", "dark hair", "face", "smile", "smiles", "shoulder", and "left shoulder" as Jenn. The thought is "Not a day goes by that you don't think about her."

After examining the known Jenn for the first time:
	award 1 point.
	

Part 3 - The Sidewalk (4 points)

The _sidewalk is a room with printed name "On the Sidewalk". "This is the sidewalk in front of the house you grew up in."


The sidewalk is scenery in the _sidewalk. The description is "Your standard concrete sidewalk.  Although it appears something has been written on it in red chalk."

After examining the sidewalk for the first time:
	award 1 point.

The concrete is part of the sidewalk. The description is "Looks like good old poured grey concrete."

After examining the concrete for the first time:
	award 1 point.

The writing is part of the sidewalk. The description is "Faded with time and footsteps, someone wrote what looks like...[paragraph break]     [italic type]J was here[roman type]."

After examining the writing for the first time:
	award 1 point.

The red chalk is part of the sidewalk. The description is "This chalk that the writing has been done with looks like the kind that comes in those really fat sticks."

After examining the red chalk for the first time:
	award 1 point.


Part 4 - The House (8 points)

Your old house is scenery in the _sidewalk. Understand "your house" and "your old house" as your old house. The description is "Painted a different color now, [the noun] still has that front porch and the big picture window."

After examining your old house the first time:
	award 1 point.
	
House color is part of your old house. The description is "You remember the house painted grey with cranberry trim but now it's a pale yellow with dark yellow trim." Understand "grey", "cranberry", "yellow", "pale yellow", "dark yellow", and "trim" as house color.

After examining the house color for the first time:
	award 1 point.
	
The front porch is part of your old house. The description is "That porch was a great place to sit on summer evenings."

After examining the front porch for the first time:
	award 1 point.
	
The picture window is part of the house. The description is "You recall peering out of this window to check the weather."

After examining the picture window for the first time:
	award 1 point.
	
The weather is backdrop in the _sidewalk. The description is "The skies are partly cloudy, 71 degrees, there is a breeze, not sure about the humidity."

After examining the weather for the first time:
	award 1 point.
	
The clouds are a backdrop in the _sidewalk. Understand "sky", "skies", "cloudy" and "partly cloudy" as clouds. The description is "The clouds above you seem like a soft rug colored grey and white."

After examining the clouds for the first time:
	award 1 point.
	
The breeze is backdrop in the _sidewalk. Understand "wind", "west", "westerly", and "direction" as the breeze. The description is "Light, gentle, and blowing in a westerly direction... this breeze is probably blowing 10 miles an hour."

After examining the breeze for the first time:
	award 1 point.
	
The humidity is backdrop in the _sidewalk. The description is "Not quite knowing how one just 'examines' humidity, you try anyway and realize it's dry the way you like it."

After examining the humidity for the first time:
	award 1 point.


Part 5 - Miscellaneous

Instead of going nowhere:
	say "You decide you would rather stay put.  It's important for you to look things over and think."
	
The -things are a backdrop. They are everywhere. Understand "things" as -things. The description is "Yes!  That is the point here:  to examine everything."

Instead of dropping something:
	say "There is no reason to throw anything away."